48. draw

[ < ]

[ > ]

[ << ]

[ Up ]

[ >> ]

[Top]

[Contents]

[Index]

[ ? ]

48.1 Introduction to draw

draw is a Maxima-Gnuplot interface.

There are three main functions to be used at Maxima level: draw2d, draw3d and draw.

Follow this link for more elaborated examples of this package:

http://www.telefonica.net/web2/biomates/maxima/gpdraw

You need Gnuplot 4.2 to run this program.

@ref{Category: Plotting} · @ref{Category: Share packages} · @ref{Category: Package draw}

[ < ]

[ > ]

[ << ]

[ Up ]

[ >> ]

[Top]

[Contents]

[Index]

[ ? ]

48.2 Functions and Variables for draw

Graphic option: xrange

Default value: auto

If xrange is auto, the range for the x coordinate is computed automatically.

If the user wants a specific interval for x, it must be given as a Maxima list, as in xrange=[-2, 3].

Since this is a global graphics option, its position in the scene description does not matter.

Example:

(%i1) load(draw)$
(%i2) draw2d(xrange = [-3,5],
             explicit(x^2,x,-1,1))$

See also contour.

@ref{Category: Package draw}

Graphic option: columns

Default value: 1

columns is the number of columns in multiple plots.

Since this is a global graphics option, its position in the scene description does not matter. It can be also used as an argument of function draw.

Example:

(%i1) load(draw)$
(%i2) scene1: gr2d(title="Ellipse",
                   nticks=30,
                   parametric(2*cos(t),5*sin(t),t,0,2*%pi))$
(%i3) scene2: gr2d(title="Triangle",
                   polygon([4,5,7],[6,4,2]))$
(%i4) draw(scene1, scene2, columns = 2)$

@ref{Category: Package draw}

Graphic option: ip_grid

Default value: [50, 50]

ip_grid sets the grid for the first sampling in implicit plots.

This option is relevant only for implicit objects.

@ref{Category: Package draw}

Graphic option: ip_grid_in

Default value: [5, 5]

ip_grid_in sets the grid for the second sampling in implicit plots.

This option is relevant only for implicit objects.

@ref{Category: Package draw}

Graphic option: x_voxel

Default value: 10

x_voxel is the number of voxels in the x direction to be used by the marching cubes algorithm implemented by the 3d implicit object.

@ref{Category: Package draw}

Graphic option: y_voxel

Default value: 10

y_voxel is the number of voxels in the y direction to be used by the marching cubes algorithm implemented by the 3d implicit object.

@ref{Category: Package draw}

Graphic option: z_voxel

Default value: 10

z_voxel is the number of voxels in the z direction to be used by the marching cubes algorithm implemented by the 3d implicit object.

@ref{Category: Package draw}

Scene constructor: gr2d (graphic option, ..., graphic object, ...)

Function gr2d builds an object describing a 2D scene. Arguments are graphic options and graphic objects. This scene is interpreted sequentially: graphic options affect those graphic objects placed on its right. Some graphic options affect the global appearence of the scene.

This is the list of graphic objects available for scenes in two dimensions: points, polygon, rectangle, bars, ellipse, label, vector, explicit, implicit, polar, parametric, image and geomap.

See also the following global graphic options: xrange, yrange, logx, logy, terminal, grid, title, xlabel, ylabel, xtics, ytics, xtics_rotate, ytics_rotate, xtics_axis, ytics_axis, xaxis, yaxis, xaxis_width, yaxis_width, xaxis_type, yaxis_type, xaxis_color, yaxis_color, xy_file, file_name, pic_width, pic_height, eps_width, eps_height, user_preamble, axis_bottom, axis_left, axis_top and axis_right.

To make use of this function, write first load(draw).

@ref{Category: Package draw}

Scene constructor: gr3d (graphic option, ..., graphic object, ...)

Function gr3d builds an object describing a 3d scene. Arguments are graphic options and graphic objects. This scene is interpreted sequentially: graphic options affect those graphic objects placed on its right. Some graphic options affect the global appearence of the scene.

This is the list of graphic objects available for scenes in three dimensions: points, label, vector, explicit, implicit, parametric, parametric_surface and geomap.

See also the following global graphic options: xrange, yrange, zrange, logx, logy, logz, terminal, grid, title, xlabel, ylabel, zlabel, xtics, ytics, ztics, xtics_rotate, ytics_rotate, ztics_rotate, xtics_axis, ytics_axis, ztics_axis, xaxis, yaxis, zaxis, xaxis_width, yaxis_width, zaxis_width, xaxis_type, yaxis_type, zaxis_type, xaxis_color, yaxis_color, zaxis_color, xy_file, user_preamble, axis_bottom, axis_left, axis_top, file_name, pic_width, pic_height, eps_width, eps_height, axis_right, rot_vertical, rot_horizontal, axis_3d, xu_grid, yv_grid, surface_hide, contour, contour_levels, palette, colorbox and enhanced3d.

To make use of this function, write first load(draw).

@ref{Category: Package draw}

Graphic object: points ([[x1,y1], [x2,y2],...])

Graphic object: points ([x1,x2,...], [y1,y2,...])

Graphic object: points ([y1,y2,...])

Graphic object: points ([[x1,y1,z1], [x2,y2,z2],...])

Graphic object: points ([x1,x2,...], [y1,y2,...], [z1,z2,...])

Graphic object: points (matrix)

Draws points in 2D and 3D.

This object is affected by the following graphic options: point_size, point_type, points_joined, line_width, key, line_type and color.

points ([[x1,y1], [x2,y2],...]) or points ([x1,x2,...], [y1,y2,...]) plots points [x1,y1], [x2,y2], etc. If abscissas are not given, they are set to consecutive positive integers, so that points ([y1,y2,...]) draws points [1,y1], [2,y2], etc. If matrix is a two-column or two-row matrix, points (matrix) draws the associated points. If matrix is a one-column or one-row matrix, abscissas are assigned automatically.

Example:

(%i1) load(draw)$
(%i2) draw2d(
        key = "Small points",
        points(makelist([random(20),random(50)],k,1,10)),
        point_type    = circle,
        point_size    = 3,
        points_joined = true,
        key           = "Great points",
        points(makelist(k,k,1,20),makelist(random(30),k,1,20)),
        point_type    = filled_down_triangle,
        key           = "Automatic abscissas",
        color         = red,
        points([2,12,8]))$

(%i1) load(draw)$
(%i2) draw2d(
        points_joined = impulses,
        line_width    = 2,
        color         = red,
        points(makelist([random(20),random(50)],k,1,10)))$

points ([[x1,y1,z1], [x2,y2,z2],...]) or points ([x1,x2,...], [y1,y2,...], [z1,z2,...]) plots points [x1,y1,z1], [x2,y2,z2], etc. If matrix is a three-column or three-row matrix, points (matrix) draws the associated points.

Examples:

One tridimensional sample,

(%i1) load(draw)$
(%i2) load (numericalio)$
(%i3) s2 : read_matrix (file_search ("wind.data"))$
(%i4) draw3d(title = "Daily average wind speeds",
             point_size = 2,
             points(args(submatrix (s2, 4, 5))) )$

Two tridimensional samples,

(%i1) load(draw)$
(%i2) load (numericalio)$
(%i3) s2 : read_matrix (file_search ("wind.data"))$
(%i4) draw3d(
         title = "Daily average wind speeds. Two data sets",
         point_size = 2,
         key        = "Sample from stations 1, 2 and 3",
         points(args(submatrix (s2, 4, 5))),
         point_type = 4,
         key        = "Sample from stations 1, 4 and 5",
         points(args(submatrix (s2, 2, 3))) )$

@ref{Category: Package draw}

Graphic object: polygon ([[x1,y1], [x2,y2],...])

Graphic object: polygon ([x1,x2,...], [y1,y2,...])

Draws polygons in 2D.

polygon ([[x1,y1], [x2,y2],...]) or polygon ([x1,x2,...], [y1,y2,...]): plots on the plane a polygon with vertices [x1,y1], [x2,y2], etc..

This object is affected by the following graphic options: transparent, fill_color, border, line_width, key, line_type and color.

Example:

(%i1) load(draw)$
(%i2) draw2d(color      = "#e245f0",
             line_width = 8,
             polygon([[3,2],[7,2],[5,5]]),
             border      = false,
             fill_color  = yellow,
             polygon([[5,2],[9,2],[7,5]]) )$

@ref{Category: Package draw}

Graphic object: rectangle ([x1,y1], [x2,y2])

Draws rectangles in 2D.

rectangle ([x1,y1], [x2,y2]) draws a rectangle with opposite vertices [x1,y1] and [x2,y2].

This object is affected by the following graphic options: transparent, fill_color, border, line_width, key, line_type and color.

Example:

(%i1) load(draw)$
(%i2) draw2d(fill_color  = red,
             line_width  = 6,
             line_type   = dots,
             transparent = false,
             fill_color  = blue,
             rectangle([-2,-2],[8,-1]), /* opposite vertices */
             transparent = true,
             line_type   = solid,
             line_width  = 1,
             rectangle([9,4],[2,-1.5]),
             xrange      = [-3,10],
             yrange      = [-3,4.5] )$

@ref{Category: Package draw}

Graphic object: bars ([x1,h1,w1], [x2,h2,w2, ...])

Draws vertical bars in 2D.

bars ([x1,h1,w1], [x2,h2,w2, ...]) draws bars centered at values x1, x2, ... with heights h1, h2, ... and widths w1, w2, ...

This object is affected by the following graphic options: key, fill_color, fill_density and line_width.

Example:

(%i1) load(draw)$
(%i2) draw2d(
       key          = "Group A",
       fill_color   = blue,
       fill_density = 0.2,
       bars([0.8,5,0.4],[1.8,7,0.4],[2.8,-4,0.4]),
       key          = "Group B",
       fill_color   = red,
       fill_density = 0.6,
       line_width   = 4,
       bars([1.2,4,0.4],[2.2,-2,0.4],[3.2,5,0.4]),
       xaxis = true);

Graphic object: ellipse (xc, yc, a, b, ang1, ang2)

Draws ellipses and circles in 2D.

ellipse (xc, yc, a, b, ang1, ang2) plots an ellipse centered at [xc, yc] with horizontal and vertical semi axis a and b, respectively, starting at angle ang1 with an amplitude equal to angle ang2.

This object is affected by the following graphic options: nticks, transparent, fill_color, border, line_width, line_type, key and color.

Example:

(%i1) load(draw)$
(%i2) draw2d(transparent = false,
             fill_color  = red,
             color       = gray30,
             transparent = false,
             line_width  = 5,
             ellipse(0,6,3,2,270,-270),
             /* center (x,y), a, b, start & end in degrees */
             transparent = true,
             color       = blue,
             line_width  = 3,
             ellipse(2.5,6,2,3,30,-90),
             xrange      = [-3,6],
             yrange      = [2,9] )$

@ref{Category: Package draw}

Graphic object: label ([string,x,y],...)

Graphic object: label ([string,x,y,z],...)

Writes labels in 2D and 3D.

Colored labels work only with Gnuplot 4.3. This is a known bug in package draw.

This object is affected by the following graphic options: label_alignment, label_orientation and color.

label([string,x,y]) writes the string at point [x,y].

Example:

(%i1) load(draw)$
(%i2) draw2d(yrange = [0.1,1.4],
             color = "red",
             label(["Label in red",0,0.3]),
             color = "#0000ff",
             label(["Label in blue",0,0.6]),
             color = "light-blue",
             label(["Label in light-blue",0,0.9],
                   ["Another light-blue",0,1.2])  )$

label([string,x,y,z]) writes the string at point [x,y,z].

Example:

(%i1) load(draw)$
(%i2) draw3d(explicit(exp(sin(x)+cos(x^2)),x,-3,3,y,-3,3),
             color = red,
             label(["UP 1",-2,0,3], ["UP 2",1.5,0,4]),
             color = blue,
             label(["DOWN 1",2,0,-3]) )$

@ref{Category: Package draw}

Graphic object: vector ([x,y], [dx,dy])

Graphic object: vector ([x,y,z], [dx,dy,dz])

Draws vectors in 2D and 3D.

This object is affected by the following graphic options: head_both, head_length, head_angle, head_type, line_width, line_type, key and color.

vector([x,y], [dx,dy]) plots vector [dx,dy] with origin in [x,y].

Example:

(%i1) load(draw)$
(%i2) draw2d(xrange      = [0,12],
             yrange      = [0,10],
             head_length = 1,
             vector([0,1],[5,5]), /* default type */
             head_type = 'empty,
             vector([3,1],[5,5]),
             head_both = true,
             head_type = 'nofilled,
             line_type = dots,
             vector([6,1],[5,5]))$

vector([x,y,z], [dx,dy,dz]) plots vector [dx,dy,dz] with origin in [x,y,z].

Example:

(%i1) load(draw)$
(%i2) draw3d(color = cyan,
             vector([0,0,0],[1,1,1]/sqrt(3)),
             vector([0,0,0],[1,-1,0]/sqrt(2)),
             vector([0,0,0],[1,1,-2]/sqrt(6)) )$

@ref{Category: Package draw}

Graphic object: explicit (fcn,var,minval,maxval)

Graphic object: explicit (fcn,var1,minval1,maxval1,var2,minval2,maxval2)

Draws explicit functions in 2D and 3D.

explicit(fcn,var,minval,maxval) plots explicit function fcn, with variable var taking values from minval to maxval.

This object is affected by the following graphic options: nticks, adapt_depth, line_width, line_type, key, filled_func, fill_color and color.

Example:

(%i1) load(draw)$
(%i2) draw2d(line_width = 3,
             color      = blue,
             explicit(x^2,x,-3,3) )$
(%i3) draw2d(fill_color  = brown,
             filled_func = true,
             explicit(x^2,x,-3,3) )$

explicit(fcn,var1,minval1,maxval1,var2,minval2,maxval2) plots explicit function fcn, with variable var1 taking values from minval1 to maxval1 and variable var2 taking values from minval2 to maxval2.

This object is affected by the following graphic options: xu_grid, yv_grid, line_type, line_width, key, enhanced3d, meshed_surface and color.

Example:

(%i1) load(draw)$
(%i2) draw3d(key   = "Gauss",
             color = "#a02c00",
             explicit(20*exp(-x^2-y^2)-10,x,-3,3,y,-3,3),
             yv_grid     = 10,
             color = blue,
             key   = "Plane",
             explicit(x+y,x,-5,5,y,-5,5),
             surface_hide = true)$

See also filled_func for filled functions.

@ref{Category: Package draw}

Graphic object: implicit (fcn,x,xmin,xmax,y,ymin,ymax)

Graphic object: implicit (fcn,x,xmin,xmax,y,ymin,ymax,z,zmin,zmax)

Draws implicit functions in 2D and 3D.

implicit(fcn,x,xmin,xmax,y,ymin,ymax) plots the implicit function defined by fcn, with variable x taking values from xmin to xmax, and variable y taking values from ymin to ymax.

This object is affected by the following graphic options: ip_grid, ip_grid_in, line_width, line_type, key and color.

Example:

(%i1) load(draw)$
(%i2) draw2d(terminal  = eps,
             grid      = true,
             line_type = solid,
             key       = "y^2=x^3-2*x+1",
             implicit(y^2=x^3-2*x+1, x, -4,4, y, -4,4),
             line_type = dots,
             key       = "x^3+y^3 = 3*x*y^2-x-1",
             implicit(x^3+y^3 = 3*x*y^2-x-1, x,-4,4, y,-4,4),
             title     = "Two implicit functions" )$

implicit (fcn,x,xmin,xmax, y,ymin,ymax, z,zmin,zmax) plots the implicit surface defined by fcn, with variable x taking values from xmin to xmax, variable y taking values from ymin to ymax and variable z taking values from zmin to zmax. This object implements the marching cubes algorithm.

This object is affected by the following graphic options: x_voxel, y_voxel, z_voxel, line_width, line_type, key and color.

Example:

(%i1) load(draw)$
(%i2) draw3d(
        color=blue,
        implicit((x^2+y^2+z^2-1)*(x^2+(y-1.5)^2+z^2-0.5)=0.015,
                 x,-1,1,y,-1.2,2.3,z,-1,1),
        surface_hide=true);

@ref{Category: Package draw}

Graphic object: polar (radius,ang,minang,maxang)

Draws 2D functions defined in polar coordinates.

polar (radius,ang,minang,maxang) plots function radius(ang) defined in polar coordinates, with variable ang taking values from minang to maxang.

This object is affected by the following graphic options: nticks, line_width, line_type, key and color.

Example:

(%i1) load(draw)$
(%i2) draw2d(user_preamble = "set grid polar",
             nticks        = 200,
             xrange        = [-5,5],
             yrange        = [-5,5],
             color         = blue,
             line_width    = 3,
             title         = "Hyperbolic Spiral",
             polar(10/theta,theta,1,10*%pi) )$

@ref{Category: Package draw}

Graphic object: spherical (radius,azi,minazi,maxazi,zen,minzen,maxzen)

Draws 3D functions defined in spherical coordinates.

spherical (radius,azi,minazi,maxazi,zen,minzen,maxzen) plots function radius(azi,zen) defined in spherical coordinates, with azimuth azi taking values from minazi to maxazi and zenith zen taking values from minzen to maxzen.

This object is affected by the following graphic options: xu_grid, yv_grid, line_type, key and color.

Example:

(%i1) load(draw)$
(%i2) draw3d(spherical(1,a,0,2*%pi,z,0,%pi))$

@ref{Category: Package draw}

Graphic object: cylindrical (radius,z,minz,maxz,azi,minazi,maxazi)

Draws 3D functions defined in cylindrical coordinates.

cylindrical (radius,z,minz,maxz,azi,minazi,maxazi) plots function radius(z,azi) defined in cylindrical coordinates, with variable z taking values from minz to maxz and azimuth azi taking values from minazi to maxazi.

This object is affected by the following graphic options: xu_grid, yv_grid, line_type, key and color.

Example:

(%i1) load(draw)$
(%i2) draw3d(cylindrical(1,z,-2,2,az,0,2*%pi))$

@ref{Category: Package draw}

Graphic object: parametric (xfun,yfun,par,parmin,parmax)

Graphic object: parametric (xfun,yfun,zfun,par,parmin,parmax)

Draws parametric functions in 2D and 3D.

This object is affected by the following graphic options: nticks, line_width, line_type, key and color.

parametric (xfun,yfun,par,parmin,parmax) plots parametric function [xfun,yfun], with parameter par taking values from parmin to parmax.

Example:

(%i1) load(draw)$
(%i2) draw2d(explicit(exp(x),x,-1,3),
             color = red,
             key   = "This is the parametric one!!",
             parametric(2*cos(rrr),rrr^2,rrr,0,2*%pi))$

parametric (xfun,yfun,zfun,par,parmin,parmax) plots parametric curve [xfun,yfun,zfun], with parameter par taking values from parmin to parmax.

Example:

(%i1) load(draw)$
(%i2) draw3d(explicit(exp(sin(x)+cos(x^2)),x,-3,3,y,-3,3),
             color = royalblue,
             parametric(cos(5*u)^2,sin(7*u),u-2,u,0,2),
             color      = turquoise,
             line_width = 2,
             parametric(t^2,sin(t),2+t,t,0,2),
             surface_hide = true,
             title = "Surface & curves" )$

@ref{Category: Package draw}

Graphic object: image (im,x0,y0,width,height)

Renders images in 2D.

image (im,x0,y0,width,height) plots image im in the rectangular region from vertex (x0,y0) to (x0+width,y0+height) on the real plane. Argument im must be a matrix of real numbers, a matrix of vectors of length three or a picture object.

If im is a matrix of real numbers or a levels picture object, pixel values are interpreted according to graphic option palette, which is a vector of length three with components ranging from -36 to +36; each value is an index for a formula mapping the levels onto red, green and blue colors, respectively:

 0: 0               1: 0.5           2: 1
 3: x               4: x^2           5: x^3
 6: x^4             7: sqrt(x)       8: sqrt(sqrt(x))
 9: sin(90x)       10: cos(90x)     11: |x-0.5|
12: (2x-1)^2       13: sin(180x)    14: |cos(180x)|
15: sin(360x)      16: cos(360x)    17: |sin(360x)|
18: |cos(360x)|    19: |sin(720x)|  20: |cos(720x)|
21: 3x             22: 3x-1         23: 3x-2
24: |3x-1|         25: |3x-2|       26: (3x-1)/2
27: (3x-2)/2       28: |(3x-1)/2|   29: |(3x-2)/2|
30: x/0.32-0.78125                  31: 2*x-0.84
32: 4x;1;-2x+1.84;x/0.08-11.5
33: |2*x - 0.5|    34: 2*x          35: 2*x - 0.5
36: 2*x - 1

negative numbers mean negative colour component.

palette = gray and palette = color are short cuts for palette = [3,3,3] and palette = [7,5,15], respectively.

If im is a matrix of vectors of length three or an rgb picture object, they are interpreted as red, green and blue color components.

Examples:

If im is a matrix of real numbers, pixel values are interpreted according to graphic option palette.

(%i1) load(draw)$
(%i2) im: apply(
           'matrix,
            makelist(makelist(random(200),i,1,30),i,1,30))$
(%i3) /* palette = color, default */
      draw2d(image(im,0,0,30,30))$
(%i4) draw2d(palette = gray, image(im,0,0,30,30))$
(%i5) draw2d(palette = [15,20,-4],
             colorbox=false,
             image(im,0,0,30,30))$

48.3 Functions and Variables for pictures

Function: make_level_picture (data)

Function: make_level_picture (data,width,height)

Returns a levels picture object. make_level_picture (data) builds the picture object from matrix data. make_level_picture (data,width,height) builds the object from a list of numbers; in this case, both the width and the height must be given.

The returned picture object contains the following four parts:

symbol level
image width
image height
an integer array with pixel data ranging from 0 to 255. Argument data must contain only numbers ranged from 0 to 255; negative numbers are substituted by 0, and those which are greater than 255 are set to 255.

Example:

Level picture from matrix.

(%i1) load(draw)$
(%i2) make_level_picture(matrix([3,2,5],[7,-9,3000]));
(%o2)         picture(level, 3, 2, {Array:  #(3 2 5 7 0 255)})

Level picture from numeric list.

(%i1) load(draw)$
(%i2) make_level_picture([-2,0,54,%pi],2,2);
(%o2)            picture(level, 2, 2, {Array:  #(0 0 54 3)})

@ref{Category: Package draw}

Function: picturep (x): Returns true if the argument is a well formed image, and false otherwise.

·
@ref{Category: Package draw} · @ref{Category: Predicate functions}

Function: picture_equalp (x,y): Returns true in case of equal pictures, and false otherwise.

·
@ref{Category: Package draw} · @ref{Category: Predicate functions}

Function: make_rgb_picture (redlevel,greenlevel,bluelevel)

Returns an rgb-coloured picture object. All three arguments must be levels picture; with red, green and blue levels.

The returned picture object contains the following four parts:

symbol rgb
image width
image height
an integer array of length 3*width*height with pixel data ranging from 0 to 255. Each pixel is represented by three consecutive numbers (red, green, blue).

Example:

(%i1) load(draw)$
(%i2) red: make_level_picture(matrix([3,2],[7,260]));
(%o2)           picture(level, 2, 2, {Array:  #(3 2 7 255)})
(%i3) green: make_level_picture(matrix([54,23],[73,-9]));
(%o3)           picture(level, 2, 2, {Array:  #(54 23 73 0)})
(%i4) blue: make_level_picture(matrix([123,82],[45,32.5698]));
(%o4)          picture(level, 2, 2, {Array:  #(123 82 45 33)})
(%i5) make_rgb_picture(red,green,blue);
(%o5) picture(rgb, 2, 2, 
              {Array:  #(3 54 123 2 23 82 7 73 45 255 0 33)})

@ref{Category: Package draw}

Function: take_channel (im,color)

If argument color is red, green or blue, function take_channel returns the corresponding color channel of picture im. Example:

(%i1) load(draw)$
(%i2) red: make_level_picture(matrix([3,2],[7,260]));
(%o2)           picture(level, 2, 2, {Array:  #(3 2 7 255)})
(%i3) green: make_level_picture(matrix([54,23],[73,-9]));
(%o3)           picture(level, 2, 2, {Array:  #(54 23 73 0)})
(%i4) blue: make_level_picture(matrix([123,82],[45,32.5698]));
(%o4)          picture(level, 2, 2, {Array:  #(123 82 45 33)})
(%i5) make_rgb_picture(red,green,blue);
(%o5) picture(rgb, 2, 2, 
              {Array:  #(3 54 123 2 23 82 7 73 45 255 0 33)})
(%i6) take_channel(%,'green);  /* simple quote!!! */
(%o6)           picture(level, 2, 2, {Array:  #(54 23 73 0)})

@ref{Category: Package draw}

Function: negative_picture (pic): Returns the negative of a (level or rgb) picture.

·
@ref{Category: Package draw}

Function: rgb2level (pic): Transforms an rgb picture into a level one by averaging the red, green and blue channels.

·
@ref{Category: Package draw}

Function: get_pixel (pic,x,y): Returns pixel from picture. Coordinates x and y range from 0 to width-1 and height-1, respectively.

·
@ref{Category: Package draw}

Function: read_xpm (xpm_file): Reads a file in xpm and returns a picture object.

·
@ref{Category: Package draw}

[ < ]

[ > ]

[ << ]

[ Up ]

[ >> ]

[Top]

[Contents]

[Index]

[ ? ]

48.4 Functions and Variables for worldmap

Function: region_boundaries (x1,y1,x2,y2)

Detects polygonal segments of global variable boundaries_array contained in the rectangle with vertices (x1,y1) -upper left- and (x2,y2) -bottom right-.

Example:

Returns segment numbers for plotting southern Italy.

(%i1) load(draw)$
(%i2) load(worldmap)$
(%i3) region_boundaries(10.4,41.5,20.7,35.4);
(%o3)                [1846, 1863, 1864, 1881, 1888, 1894]
(%i4) draw2d(geomap(%))$

@ref{Category: Package draw}

Function: numbered_boundaries (nlist)

Draws a list of polygonal segments (boundaries), labeled by its numbers (boundaries_array coordinates). This is of great help when building new geographical entities.

Example:

Map of Europe labeling borders with their component number in boundaries_array.

(%i1) load(draw)$
(%i2) load(worldmap)$
(%i3) european_borders: 
           region_boundaries(-31.81,74.92,49.84,32.06)$
(%i4) numbered_boundaries(european_borders)$

@ref{Category: Package draw}

Function: make_polygon (nlist)

Returns a polygon object from boundary indices. Argument nlist is a list of components of boundaries_array.

Example:

Bhutan is defined by boundary numbers 171, 173 and 1143, so that make_polygon([171,173,1143]) appends arrays of coordinates boundaries_array[171], boundaries_array[173] and boundaries_array[1143] and returns a polygon object suited to be plotted by draw. To avoid an error message, arrays must be compatible in the sense that any two consecutive arrays have two coordinates in the extremes in common. In this example, the two first components of boundaries_array[171] are equal to the last two coordinates of boundaries_array[173], and the two first of boundaries_array[173] are equal to the two first of boundaries_array[1143]; in conclussion, boundary numbers 171, 173 and 1143 (in this order) are compatible and the colored polygon can be drawn.

(%i1) load(draw)$
(%i2) load(worldmap)$
(%i3) Bhutan;
(%o3)                        [[171, 173, 1143]]
(%i4) boundaries_array[171];
(%o4) {Array:  
       #(88.750549 27.14727 88.806351 27.25305 88.901367 27.282221
         88.917877 27.321039)}
(%i5) boundaries_array[173];
(%o5) {Array:
       #(91.659554 27.76511 91.6008 27.66666 91.598022 27.62499
         91.631348 27.536381 91.765533 27.45694 91.775253 27.4161 
         92.007751 27.471939 92.11441 27.28583 92.015259 27.168051
         92.015533 27.08083 92.083313 27.02277 92.112183 26.920271
         92.069977 26.86194 91.997192 26.85194 91.915253 26.893881
         91.916924 26.85416 91.8358 26.863331 91.712479 26.799999 
         91.542191 26.80444 91.492188 26.87472 91.418854 26.873329
         91.371353 26.800831 91.307457 26.778049 90.682457 26.77417
         90.392197 26.903601 90.344131 26.894159 90.143044 26.75333
         89.98996 26.73583 89.841919 26.70138 89.618301 26.72694 
         89.636093 26.771111 89.360786 26.859989 89.22081 26.81472
         89.110237 26.829161 88.921631 26.98777 88.873016 26.95499
         88.867737 27.080549 88.843307 27.108601 88.750549 
         27.14727)}
(%i6) boundaries_array[1143];
(%o6) {Array:  
       #(91.659554 27.76511 91.666924 27.88888 91.65831 27.94805 
         91.338028 28.05249 91.314972 28.096661 91.108856 27.971109
         91.015808 27.97777 90.896927 28.05055 90.382462 28.07972
         90.396088 28.23555 90.366074 28.257771 89.996353 28.32333
         89.83165 28.24888 89.58609 28.139999 89.35997 27.87166 
         89.225517 27.795 89.125793 27.56749 88.971077 27.47361
         88.917877 27.321039)}
(%i7) Bhutan_polygon: make_polygon([171,173,1143])$
(%i8) draw2d(Bhutan_polygon)$

@ref{Category: Package draw}

Function: make_poly_country (country_name)

Makes the necessary polygons to draw a colored country. If islands exist, one country can be defined with more than just one polygon.

Example:

(%i1) load(draw)$
(%i2) load(worldmap)$
(%i3) make_poly_country(India)$
(%i4) apply(draw2d, %)$

@ref{Category: Package draw}

Function: make_poly_continent (continent_name)

Function: make_poly_continent (country_list)

Makes the necessary polygons to draw a colored continent or a list of countries.

Example:

(%i1) load(draw)$
(%i2) load(worldmap)$
(%i3) /* A continent */
      make_poly_continent(Africa)$
(%i4) apply(draw2d, %)$
(%i5) /* A list of countries */
      make_poly_continent([Germany,Denmark,Poland])$
(%i6) apply(draw2d, %)$

@ref{Category: Package draw}

[ << ]

[ >> ]

[Top]

[Contents]

[Index]

[ ? ]

This document was generated by root on July, 13 2009 using texi2html 1.76.